WMI でイベントを取得してみよう - WMI Step
Topics
今まではプロパティを取得・設定したりメソッドを実行していたりしまいたが、これだけでは芸がないと思ったのでこのステップではイベントの取得方法を紹介したいと思います。
今回は VBS を使用したサンプルを紹介しますが基本的には VB でも問題なく使用可能です。 (単に VB でやると私の環境では固まることがまれにあったので、今回は VBS で書いているだけだったりします…。)
Sample Code
Option Explicit
Dim PrcEvt
Dim Prc
Dim Locator
Dim Service
Dim MesStr
Set Locator = WScript.CreateObject("WbemScripting.SWbemLocator")
Set Service = Locator.ConnectServer
Set Prc = Service.ExecNotificationQuery _
("SELECT * FROM __InstanceCreationEvent " _
& "WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'")
Set PrcEvt = Prc.NextEvent
If PrcEvt.TargetInstance.Name = "NOTEPAD.EXE" Then
MsgBox "メモ帳が起動しました。OK を押すとメモ帳を終了します。"
PrcEvt.TargetInstance.Terminate
End If
Set PrcEvt = Nothing
Set Prc = Nothing
Set Locator = Nothing
Set Service = Nothing
Comment
では実行してみましょう。
実行するとこのスクリプトはあるイベントが発生するまで待機して待ちづける事になります。
これを実現しているのは
Set Prc = Service.ExecNotificationQuery _
("SELECT * FROM __InstanceCreationEvent " _
& "WITHIN 1 WHERE TargetInstance ISA 'Win32_Process'")
Set PrcEvt= Prc.NextEvent
になります。
ExecNotificationQuery メソッドが WQL で指定した条件での通知を待つためのオブジェクトを作成しています。このメソッドを実行すると SWbemEventSource 型が帰ってきます。
この型には NextEvent メソッドが用意されていて WQL で指定したクエリーのイベントが発生するまでプログラムがそこで待つことになります。
今回は Win32_Process を使用したサンプルで何かアプリケーションを実行してプロセスが作成するイベントが発生するまで待つ形になります。
WQL で指定している WITHIN 句はポーリングする間隔 (秒) です。待ち続けている間ここで指定したポーリングの間隔でプロセスが作成されたか否かをチェックします。
__instancecreationevent はインスタンスが作成された際に発生するイベントを取得することを示しています。
TargetInstance isa 'Win32_Process' という形で明示しておく事によりイベント発生時にはTargetInstance を経由して Win32_Process の各種値の取得が可能です。
最後にイベントが発生した際に起動されたプロセスが「NOTEPAD.EXE」であればメッセージボックスを表示して勝手に終了させてしまいます。
メモ帳が起動したかどうか確認するために PrcEvt.TargetInstance.Name という記述を行っていますがこれは、イベントが発生した際の情報が Win32_Process クラスの実装のとおり PrcEvt.TargetInstance で参照できるようになるため可能になります。
